Delphiな小技

RealtimeRateFX

boon_net — 2007-11-14T17:13:17+09:00

■ ダウンロード ■
Version 1.01 (2007/12/03)
Version 1.00 (2007/11/15)

■ ソフトウェア概要 ■
RealtimeRateFX（リアルタイムレートエフエックス）は、リアルタイムな為替レートをガジェット状に背景を透明にしてデスクトップ上に表示できるソフトウェアです。
デスクトップの片隅に配置して、いつでもレートを監視できるよう開発しました。

表示可能な通貨ペアは、USD/JPY、EUR/JPY、EUR/USD、AUD/JPY、GBP/JPY、NZD/JPY、CAD/JPY、CHF/JPY、HKD/JPY、GBP/USD、USD/CHF、ZAR/JPYの12種類で、このうち最大10ペアを表示可能です。
レートは、各ペアに対し Bid - Ask (Change) の順で表示されます。

このソフトウェアの動作には、インターネット接続が必須です。
又、レート配信元の仕様変更等により正確にレートを表示できなくなる可能性があります。
その場合、バージョンアップにより対応予定です。

■ 使用方法 ■
タスクトレイ上のアイコン、もしくはロゴの上で右クリックするとメニューが表示されます。

設定(S)・・・・設定画面を表示します。
常に手前に表示(T)・・・・常に手前に表示するかどうかを切り替えできます。
背景の透明化(C)・・・・背景の透明化と非透明化を切り替えできます。
バージョン情報(A)・・・・バージョン情報を表示します。
終了(X)・・・・ソフトウェアを終了します。

設定できる内容は、表示通貨ペア、更新間隔、文字色です。

表示通貨ペア・・・・表示したい通貨ペアを選択でき、表示順も設定できます。
更新間隔・・・・10秒から300秒まで1秒刻みで設定可能。
文字色・・・・背景を透明にして、壁紙の色等により文字が見にくくなった場合文字色を変更できる。

表示部の移動は、ロゴをドラッグしてください。

値の名前を列挙する

boon_net — 2007-08-09T12:20:01+09:00

サンプルは、開いているキー以下に存在する値の名前を Memo1 に列挙します。

uses節に、Registry ユニットを追加して下さい。

uses
  Registry;

procedure TForm1.Button1Click(Sender: TObject);
var
  Reg: TRegistry;
begin
  Reg := TRegistry.Create;
  try
    Reg.Rootkey := HKEY_LOCAL_MACHINE;
    if Reg.OpenKey('SOFTWARE\Test', True) then
      // 値の名前を Memo1 に列挙
      Reg.GetValueNames(Memo1.Lines)
    else
      ShowMessage('キーを開けませんでした');
  finally
    Reg.CloseKey;
    Reg.Free;
  end;
end;

値の削除

boon_net — 2007-08-09T12:19:17+09:00

サンプルは、レジストリ値を設定し、その値を削除します。

uses節に、Registry ユニットを追加して下さい。

uses
  Registry;

procedure TForm1.Button1Click(Sender: TObject);
var
  Reg: TRegistry;
begin
  Reg := TRegistry.Create;
  try
    Reg.Rootkey := HKEY_LOCAL_MACHINE;
    if Reg.OpenKey('SOFTWARE', False) then
    begin
      Reg.WriteString('Test', 'Delphiな小技');
      // 値の削除及び、失敗時の処理
      if Reg.DeleteValue('Test') then
        ShowMessage('値の削除に成功しました')
      else
        ShowMessage('値の削除に失敗しました');
    end
    else
      ShowMessage('キーを開けませんでした');
  finally
    Reg.CloseKey;
    Reg.Free;
  end;
end;

値の設定と取得

boon_net — 2007-08-09T12:18:19+09:00

レジストリ値の設定には、書き込む際に型を指定する必要があり、値の取得も同様です。
サンプルは、レジストリ値を文字列型、整数型、実数型、論理型、日付型、時刻型として書き込み、さらに値を取得して Memo1 に返します。

uses節に、Registry ユニットを追加して下さい。

uses
  Registry;

procedure TForm1.Button1Click(Sender: TObject);
var
  Reg: TRegistry;
begin
  Reg := TRegistry.Create;
  try
    Reg.Rootkey := HKEY_LOCAL_MACHINE;
    if Reg.OpenKey('SOFTWARE\Test', True) then
    begin
      // 値の設定
      Reg.WriteString('String', 'Delphiな小技');
      Reg.WriteInteger('Integer', 321);
      Reg.WriteFloat('Float', 123.456);
      Reg.WriteBool('Boolean', False);
      Reg.WriteDate('Date', Date);
      Reg.WriteTime('Time', Time);

      // 値の取得
      Memo1.Lines.Add(Reg.ReadString('String'));
      Memo1.Lines.Add(IntToStr(Reg.ReadInteger('Integer')));
      Memo1.Lines.Add(FloatToStr(Reg.ReadFloat('Float')));
      Memo1.Lines.Add(BoolToStr(Reg.ReadBool('Boolean'), True));
      Memo1.Lines.Add(DateToStr(Reg.ReadDate('Date')));
      Memo1.Lines.Add(TimeToStr(Reg.ReadTime('Time')));
    end
    else
      ShowMessage('キーを開けませんでした');
  finally
    Reg.CloseKey;
    Reg.Free;
  end;
end;

キー名を列挙する

boon_net — 2007-08-08T20:21:30+09:00

サンプルは、開いているキー以下に存在するキー名を Memo1 に列挙します。

uses節に、Registry ユニットを追加して下さい。

uses
  Registry;

procedure TForm1.Button1Click(Sender: TObject);
var
  Reg: TRegistry;
begin
  // Reg のインスタンス化
  Reg := TRegistry.Create;
  try
    // ルートキーを設定
    Reg.Rootkey := HKEY_LOCAL_MACHINE;
    // キーを開く
    if Reg.OpenKey('SOFTWARE', False) then
      // Memo1 にキー名を列挙する
      Reg.GetKeyNames(Memo1.Lines)
    else
      ShowMessage('キーのオープンに失敗しました');
  finally
    // キーを閉じる
    Reg.CloseKey;
    // Reg を破棄
    Reg.Free;
  end;
end;

キーのオープンとクローズ

boon_net — 2007-08-08T20:20:27+09:00

値を書き込んだり、読み込んだりする前に必ずキーを開かなくてはいけません。
書き込み及び、読み込み終わったキーは必ず閉じる必要があります。
以下のサンプルは、キーを開いて閉じます。

uses節に、Registry ユニットを追加して下さい。

uses
  Registry;

procedure TForm1.Button1Click(Sender: TObject);
var
  Reg: TRegistry;
begin
  // Reg のインスタンス化
  Reg := TRegistry.Create;
  try
    // ルートキーを設定
    Reg.Rootkey := HKEY_LOCAL_MACHINE;

    // キーを開く（存在しなければ作成する）
    if Reg.OpenKey('SOFTWARE\Test', True) then
      ShowMessage('キーを開きました')
    else
      ShowMessage('キーを開けませんでした');

  finally
    // キーを閉じる
    Reg.CloseKey;
    // Reg を破棄
    Reg.Free;
  end;
end;

キーの作成と削除

boon_net — 2007-08-08T20:19:10+09:00

サンプルは、レジストリにキーを作成し削除します。
キーは、オープン時に存在しない場合、作成することも出来ます。

uses節に、Registry ユニットを追加して下さい。

uses
  Registry;

procedure TForm1.Button1Click(Sender: TObject);
var
  Reg: TRegistry;
begin
  // Reg のインスタンス化
  Reg := TRegistry.Create;
  try
    // ルートキーを設定
    Reg.Rootkey := HKEY_LOCAL_MACHINE;

    // キーの作成及び、失敗時の処理
    if Reg.CreateKey('SOFTWARE\Test') then
      ShowMessage('キーの作成に成功しました')
    else
      ShowMessage('キーの作成に失敗しました');

    // キーの削除及び、失敗時の処理
    if Reg.DeleteKey('SOFTWARE\Test') then
      ShowMessage('キーの削除に成功しました')
    else
      ShowMessage('キーの削除に失敗しました');

  finally
    // Reg を破棄
    Reg.Free;
  end;
end;

ファイルから画像を挿入する

boon_net — 2007-08-08T12:16:32+09:00

サンプルは、Excel に画像ファイルを挿入しサイズを任意に変更します。
jpg 以外にも gif や png 等もそのままのフォーマットで挿入できるため、ファイルサイズを小さくする事ができる。

uses
  ComObj;

procedure TForm1.Button1Click(Sender: TObject);
var
  Excel: Variant;
  xlApplication: Variant;
  xlWorkBook: Variant;
  xlWorkSheet: Variant;
  xlPicture: Variant;
begin
  // Excelの起動
  try
    Excel := CreateOleObject('Excel.Application');
    xlApplication := Excel.Application;
  except
    // 起動失敗時の処理
    on EOleSysError do
    begin
      ShowMessage('Excelを起動できません');
      Excel := Unassigned;
      Exit;
    end;
  end;

  // ウィンドウの表示
  xlApplication.Visible := True;
  // ブックを作成
  xlWorkBook := xlApplication.Workbooks.Add;
  // Sheet1 を選択
  xlWorkSheet := xlWorkBook.Worksheets['Sheet1'];
  // シートをアクティブにする
  xlWorkSheet.Activate;
  // 貼り付けたい位置のセルを選択
  xlWorkSheet.Range['B3', 'B3'].Select;

  // 画像をファイルから挿入
  xlPicture := xlWorkSheet.Pictures.Insert('c:\test.jpg');
  xlPicture.Select;

  // 画像を自由に収縮（水平垂直とも0.5倍）
  xlPicture.ShapeRange.ScaleWidth(0.5, False);
  xlPicture.ShapeRange.ScaleHeight(0.5, False);

  // オブジェクトを初期化する
  Excel := Unassigned;
  xlApplication := Unassigned;
  xlWorkBook := Unassigned;
  xlWorkSheet := Unassigned;
  xlPicture := Unassigned;
end;

クリップボード経由の画像貼り付け

boon_net — 2007-08-08T12:15:06+09:00

サンプルは Excel にクリップボードを経由して画像を貼り付けます。
ただし、クリップボードには Bitmap形式でしか格納出来ないため、クリップボードを経由させるとファイルサイズが大きくなってしまう可能性がある。
ファイルサイズを小さくしたい場合は、一度画像をファイルに保存し、ファイルから画像を挿入するのがおすすめ。

uses
  ComObj, Clipbrd;

procedure TForm1.Button1Click(Sender: TObject);
var
  Excel: Variant;
  xlApplication: Variant;
  xlWorkBook: Variant;
  xlWorkSheet: Variant;
  bmp: TBitmap;
begin
  // Excelの起動
  try
    Excel := CreateOleObject('Excel.Application');
    xlApplication := Excel.Application;
  except
    // 起動失敗時の処理
    on EOleSysError do
    begin
      ShowMessage('Excelを起動できません');
      Excel := Unassigned;
      Exit;
    end;
  end;

  // ウィンドウの表示
  xlApplication.Visible := True;
  // ブックを作成
  xlWorkBook := xlApplication.Workbooks.Add;
  // Sheet1 を選択
  xlWorkSheet := xlWorkBook.Worksheets['Sheet1'];
  // シートをアクティブにする
  xlWorkSheet.Activate;
  // 貼り付けたい位置のセルを選択
  xlWorkSheet.Range['B3', 'B3'].Select;

  // bmp のインスタンス化
  bmp := TBitmap.Create;
  try
    // Bitmapファイル読み込み
    bmp.LoadFromFile('c:\test.bmp');
    // クリップボードにコピー
    Clipboard.Assign(bmp);
    // クリップボードから貼り付ける
    xlWorkSheet.Paste;
  finally
    // bmp の破棄
    bmp.Free;
  end;

  // オブジェクトを初期化する
  Excel := Unassigned;
  xlApplication := Unassigned;
  xlWorkBook := Unassigned;
  xlWorkSheet := Unassigned;
end;

文字列に改行コードを入力する

boon_net — 2007-08-06T22:45:58+09:00

改行コード(LF, CR)はそれぞれ、ASCIIコード(0Ah, 0Dh)を示します。
改行コードはOSによって違うため、必要に応じて使い分けが必要です。
Macintosh系では #13 、UNIX系では #10 、Windows系では #13#10 となります。

サンプルは、メッセージを3行に分けて表示します。

procedure TForm1.Button1Click(Sender: TObject);
begin
  // 3行に分けてメッセージを表示する
  ShowMessage('１行目' + #13#10 + '２行目' + #13#10 + '３行目');
end;

文字列から部分文字列を検索する（複数個所の場合）

boon_net — 2007-07-19T22:01:55+09:00

文字列から部分文字列を複数箇所検索する場合、StrUtils ユニットにある PosEx 関数を使用します。
しかし、私の知る限りでは、Delphi 6 に PosEx 関数は存在せず、マルチバイト文字にも対応していないようなので、ここでは以前どこかで教えてもらってメモっておいた AnsiPosEx 関数を使用します。

function AnsiPosEx(const SubStr, S: String;
  Offset: Cardinal = 0): Cardinal;
var
  P: PChar;
begin
  if Offset = 0 then
    Result := AnsiPos(SubStr, S)
  else
  begin
    P := PChar(S);
    if ByteType(S, Offset) = mbLeadByte then
      Inc(Offset);
    Inc(P, Offset);
    P := AnsiStrPos(P, PChar(SubStr));
    if Assigned(P) then
      Result := P - PChar(S) +1
    else
      Result := 0;
  end;
end;

サンプルでは、Memo1 に書き込まれた内容から、Edit1 の文字列を検索し、Label1 へヒット数を返します。
また、カーソル位置から順番に検索個所を反転表示します。

Sample Download

procedure TForm1.Button1Click(Sender: TObject);
var
  i: Integer;
  Counter: Integer;
  Offset: Integer;
  Str: String;
begin
  // Memo1 の内容を Str へコピー
  Str := Memo1.Lines.Text;
  // 変数初期化
  i := 0;
  Counter := 0;

  // 検索ワードのヒット数をカウント
  Repeat
    i := AnsiPosEx(Edit1.Text, Str, i);
    if i > 0 then
      Inc(Counter);
  until i = 0;
  // ヒット数を書き出し
  Label1.Caption := '検索ヒット数　：　' + IntToStr(Counter);

  // ヒットした場合、検索ワードを選択し反転表示する
  if Counter > 0 then
  begin
    // カーソル位置より後で検索
    Offset := Memo1.SelStart + Memo1.SelLength;
    i := AnsiPosEx(Edit1.Text, Str, Offset);
    // カーソルの位置が最後の検索ワードよりも後だった場合、
    // オフセットを 0 に戻し再検索
    if i = 0 then
    begin
      Offset := 0;
      i := AnsiPosEx(Edit1.Text, Str, Offset);
    end;
    // 検索ワードを反転表示
    Memo1.SelStart := i -1;
    Memo1.SelLength := Length(Edit1.Text);
  end;
end;

文字列から部分文字列を検索する（単一個所の場合）

boon_net — 2007-07-19T21:37:55+09:00

文字列から部分文字列を検索する場合、Pos 関数か、全角文字（マルチバイト文字）を含む場合は AnsiPos 関数を使用します。
Pos 関数（AnsiPos 関数）は、文字列から部分文字列を検索して、最初に見つかった位置を返し、見つからなかった場合は 0 を返します。

検索語句が文字列の中に複数ある場合はこちら

サンプルは、Edit1 の文字列から Edit2 の文字列を検索し、結果を Edit3 に返します。

procedure TForm1.Button1Click(Sender: TObject);
var
  i: Integer;
begin
  // Edit1 から Edit2 を検索し、変数 i に結果を返す。
  i := Pos(Edit2.Text, Edit1.Text);
  if i = 0 then
    // 見つからなかった場合の処理
    Edit3.Text := '見つかりません'
  else
    // 見つかった場合の処理
    Edit3.Text := IntToStr(i) + '文字目に見つかりました';
end;

文字列をJISコード（ASCIIコード）へ変換

boon_net — 2007-07-18T19:13:08+09:00

半角文字と全角文字の区別には、ByteType関数を使用します。
ByteType関数は、指定されたバイトが完全な 1 文字を表すときに mbSingleByte、マルチバイト文字の最初のバイトを表すときに mbLeadByte、マルチバイト文字の 2 番目のバイトを表すときに mbTrailByte を返します。

以下のサンプルは、Edit1 に入力された文字列のJISコード(ASCIIコード)を、Memo1 に列挙します。

procedure TForm1.Button1Click(Sender: TObject);
var
  s, Temp: String;
  i: Integer;
begin
  s := Edit1.Text;
  Memo1.Clear;
  // 文字列のバイト数分ループする
  for i := 1 to Length(s) do
  begin
    // シングルバイト文字の処理
    if ByteType(s, i) = mbSingleByte then
      Memo1.Lines.Add(IntToHex(Ord(s[i]), 2));
    // マルチバイト文字の上位バイト処理
    if ByteType(s, i) = mbLeadByte then
      Temp := IntToHex(Ord(s[i]), 2);
    // マルチバイト文字の下位バイト処理
    if ByteType(s, i) = mbTrailByte then
    begin
      Temp := Temp + IntToHex(Ord(s[i]), 2);
      Memo1.Lines.Add(Temp);
    end;
  end;
end;

文字列から部分文字列をコピーする

boon_net — 2007-07-17T19:19:54+09:00

部分文字列のコピーには Copy 関数を使用します。
だたし、全角文字（マルチバイト文字）は、2文字として処理されますので注意が必要です。

サンプルは、Edit1 に入力された文字列の 1文字目から 6文字分を Edit2 へ、7文字目から 6文字分を Edit3 に出力します。

procedure TForm1.Button1Click(Sender: TObject);
var
  Src, Dest: String;
begin
  // Edit1 の内容を Src にコピー
  Src := Edit1.Text;
  // Srcの 1文字目から 6文字分をDestへコピー
  Dest := Copy(Src, 1, 6);
  Edit2.Text := Dest;
  // Srcの 7文字目から 6文字分をDestへコピー
  Dest := Copy(Src, 7, 6);
  Edit3.Text := Dest;
end;

文字列から部分文字列を削除する

boon_net — 2007-07-17T19:18:17+09:00

部分文字列の削除には Delete 手続きを使用します。
全角文字（マルチバイト文字）は、2文字として扱われるので注意が必要です。

サンプルは、Edit1 の文字列の 7文字目から 5文字分を削除し、Edit2 へ返します。

procedure TForm1.Button1Click(Sender: TObject);
var
  Src: String;
begin
  // Edit1 の内容を Src にコピー
  Src := Edit1.Text;
  // 7文字目から 5文字分削除する
  Delete(Src, 7, 5);
  // Edit2 へ書き出し
  Edit2.Text := Src;
end;